How to create an install.properties file

stpendl · 2009-03-25 10:24:49

Is there a way to create an install.properties file during a manual installation, which can be used as a template for further silent installations :?

I have read the documentation about silent installations, but it would be better to let an installation create the file instead of using a text editor to manually create it.

In addition must the file be named install.properties or can I have one for each platform, e.g. install_x86.properties, install_AMD64.properties, etc. :?

stpendl · 2009-03-27 11:47:02

I am currently using the following batch file for a silent installation on Windows x86 and x64.
Place this script in the folder where you have copied the contents of the installation CD.
If you need different settings, install manually and examine the file "{VERICUT Install Location}\Uninstaller\installvariables.properties".

set script_path=%~dp0
set exit_code=-99
set lic_serv=CHANGE_ME
set vc_ver=622

"%~dp0\vcredist_x86.exe"

goto :%PROCESSOR_ARCHITECTURE%

:AMD64
"%~dp0\vcredist_x64.exe"

:x86

set install_path_tmp=%ProgramFiles%\cgtech%vc_ver%
set install_path=%install_path_tmp:\=$/$%

echo USER_INSTALL_DIR=%install_path%>"%TMP%\install.properties"
echo CHOSEN_INSTALL_SET=Full>>"%TMP%\install.properties"

if %PROCESSOR_ARCHITECTURE% == x86 echo VERICUT_PLATFORMS="Windows 32-bit","">>"%TMP%\install.properties"
if %PROCESSOR_ARCHITECTURE% == AMD64 echo VERICUT_PLATFORMS="","Windows 64-bit">>"%TMP%\install.properties"

echo LICENSE_SERVER_HOSTNAME="%lic_serv%">>"%TMP%\install.properties"
echo DEFAULT_BASE_LIC_VAR="1) VERICUT","","">>"%TMP%\install.properties"
echo DEFAULT_UNITS_VAR="","2) Millimeter">>"%TMP%\install.properties"

"%~dp0\install.exe" -i silent -f "%TMP%\install.properties"
if %ERRORLEVEL% GTR %exit_code% set exit_code=%ERRORLEVEL%

rem remove desktop shortcut, since it is for current user only
for %%F in ("%USERPROFILE%\Desktop\VERICUT 6*") do del /f /q "%%F"

exit /b %exit_code%

VERICUT Users' Forum

#1 2009-03-25 10:24:49

How to create an install.properties file

#2 2009-03-27 11:47:02

Re: How to create an install.properties file

Board footer